****************************************************************************
****************************************************************************
**                                                               
**  Phoenix (Free ship screen)
**
**  Copyright 2000 by Patrick Davidson.  This software may be freely
**  modified and/or copied with no restrictions.  There is no warranty.
**
**  by Patrick Davidson (pad@calc.org, http://pad.calc.org/)
**
**  Last updated November 26, 2000
**
****************************************************************************
****************************************************************************

Free_Ship:
    IFND    ti89d   
        bsr     Status_Prepare  
        BSR     Scroll_Side     
    ENDIF   
    IFD     ti89d   
        bsr     Clear_Screen_Main       
    ENDIF   

    IFND    ti89d   
        lea     sPlayer_Ship_Normal(pc),a0      
        moveq   #70,d0  
        moveq   #75,d1  
        bsr     Xor_Sprite      
        lea     sPlayer_Ship_II(pc),a0  
        moveq   #70,d0  
        moveq   #98,d1  
        bsr     Xor_Sprite      
        lea     sPlayer_Ship_III(pc),a0 
        moveq   #70,d0  
        moveq   #125,d1 
        bsr     Xor_Sprite      
    ENDIF   
    IFD     ti89d   
        lea     sPlayer_Ship_Normal(pc),a0      
        moveq   #60,d0  
        moveq   #60,d1  
        bsr     Xor_Sprite      
        lea     sPlayer_Ship_II(pc),a0  
        moveq   #60,d0  
        moveq   #77,d1  
        bsr     Xor_Sprite      
        lea     sPlayer_Ship_III(pc),a0 
        moveq   #60,d0  
        moveq   #99,d1  
        bsr     Xor_Sprite      
    ENDIF   

        bsr     Display_Screen  
        moveq   #0,d0                   ; Enable interrupts
        trap    #1      

        lea     Ship_Messages(pc),a2    
        moveq   #13,d3  
        moveq   #1,d4   
    IFND    ti89d   
        moveq   #34,d5  
    ENDIF   
    IFD     ti89d   
        moveq   #0,d0   
        bsr     Set_Font
        moveq   #6,d6
    ENDIF   
        bsr     Print_Messages  

fsloop:
    IFND    ti89d   
        bsr     Timer_Delay     
        bsr     Scroll_Side     
        bsr     Display_Screen_Sides    
    ENDIF   
        bsr     Test_Key        
        sub.w   #'1',d0 
        blt.s   fsloop  
        cmp.w   #3,d0   
        bge.s   fsloop  

        lea     enemy_bullets(a5),a2    
        moveq   #15,d2  
fskeb:  tst.w   eb_dmg(a2)
        blt.s   money
        clr.w   (a2)
money:  lea     eb_size(a2),a2  
        dbra    d2,fskeb        

        lea     bullets_data(a5),a2     
        moveq   #23,d2  
fskb:   clr.w   (a2)    
        lea     b_size(a2),a2   
        dbra    d2,fskb 

        move.w  d0,player_ship(a5)

        bsr     Wait_No_Key

        bra     New_Ship        

Ship_Messages:
        dc.b    'For',YOU,'r success so far,',0    
        dc.b    'you have been awarded with',0  
        dc.b    'with a new ship.  Please',0    
        dc.b    'select which ship',YOU,' want',0  
        dc.b    'from',THE,'options below:',0     
        dc.b    0       
        dc.b    0       
        dc.b    '1',0   
        dc.b    0       
        dc.b    0       
        dc.b    '2',0   
        dc.b    0       
        dc.b    0       
        dc.b    '3',0   

        EVEN