;;; -*- TI-Asm -*-
;;;
;;; Mimas - Assembly language IDE for the TI-83 Plus
;;; 
;;; Copyright (C) 2010 Benjamin Moody
;;;
;;; This program is free software: you can redistribute it and/or
;;; modify it under the terms of the GNU General Public License as
;;; published by the Free Software Foundation; either version 3 of the
;;; License, or (at your option) any later version.
;;;
;;; This program is distributed in the hope that it will be useful,
;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;; General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with this program.  If not, see <http://www.gnu.org/licenses/>.

;; CompileProgramDlg:
;;
;; Show the "Compile Program" dialog, allowing the user to select
;; options for compiling; then compile the program.
;;
;; Destroys:
;; - AF, BC, DE, HL, IX
;; - OP1-OP6
;; - penRow, penCol
;; - Text edit buffer
;; - Contents of LCD, plotSScreen, and saveSScreen
;; - Current program and section information
;; - Temporary assembly buffers

CompileProgramDlg:
	;; set default output name to name of input file
	ld de,asmOutputFileName
	ld a,ProtProgObj
	ld (de),a
	inc de
	ld hl,curProgFileName + 1
	BCALL _Mov8B
	xor a
	ld (de),a
;	ld (flags + asm_Flag2),a
CompileProgramDlg_Loop:
	ld hl,compileProgramLabel
	ld de,compileProgramDlgInfo
	call ShowDialogScreen
	ret c
	;; check that file name is non-empty and begins with an
	;; uppercase letter
	ld hl,asmOutputFileName + 1
	ld a,(hl)
	call IsFileNameStartChar
	jr c,CompileProgramDlg_Loop
	dec hl
	rst rMOV9TOOP1
	BCALL _ChkFindSym
	jr c,CompileProgramDlg_NewFile
	ld de,overwriteFileTitle
	ld hl,overwriteFileMsg
	ld a,1 << shiftAlpha | 1 << shiftKeepAlph
	call ShowPopupMessageShift
	cp kCapY
	jr nz,CompileProgramDlg_Loop
CompileProgramDlg_NewFile:
	call BuildProgram
	ld hl,compilationFinishedMsg
ShowSuccessPopupMessage:
	ld de,successTitle
	jq_ ShowPopupMessage