Début en TI Basic : algorithme pour le 2nd degré [Résolu]

[Amayarux]

Bonjour à tous.

Je me lance dans la programmation en TI Basic pour importer mes anciens programmes de Casio Graph 35+ sur ma nouvelle TI NSpire CX CAS.

Depuis toute à l'heure, j'essaye de remettre mon programme sur les trinômes (un classique au lycée) je fais face à un problème lorsque je vérifie la syntaxe de mon algorithme avant de l'enregistrer, puis une console s'affiche avec le message suivant : "Manque d’une instruction de début ou de fin de bloc."

Même si la plupart des commandes sont similaires entre Casio Basic et TI Basic, je ne sais pas quoi changer ... (surtout que le programme tournait parfaitement sur ma Casio).

Voilà, je vous met le code que j'ai tapé en espérant que quelqu'un puisse m'apporter des réponses

Code: Select all

Define trinôme()=
Prgm
:Disp"f(x)=ax²+bx+c"
:Request"Entrez a",a
:While a=0
:Disp"Erreur : a≠0"
:Request"Entrez a",a
:EndWhile
:Request"Entrez b",b
:Request"Entrez c",c
:d=b^(2)-4ac
:Disp"Discriminant Δ =",d
:If d=0
:Then Goto 1
:EndIf
:If d<0
:Then Goto 2
:EndIf
:If d>0
:Then Goto 3
:EndIf
:Lbl 1
:Disp"Une solution réelle :"
:Disp"x =",(-b)/2a
:Stop
:Lbl 2
:Disp"Deux solutions complexes :"
:Disp"x₁ =",(-b-i√(-d))/2a
:Disp"x₂ =",(-b+i√(-d))/2a
:Stop
:Lbl 3
:Disp"Deux solutions réelles :"
:Disp"x₁ =",(-b-√(d))/2a
:Disp"x₂ =",(-b+√(d))/2a
:Stop
:EndPrgm


Merci d'avance à tous.
Amayarux

[Excale]

Code: Select all

Define trinôme()=
Prgm
:Disp "f(x)=ax²+bx+c"
:Request "Entrez a",a
:While a=0
:Disp "Erreur : a≠0"
:Request "Entrez a",a
:EndWhile
:Request "Entrez b",b
:Request "Entrez c",c
:d:=b^(2)-4a*c
:Disp "Discriminant Δ =",d
:If d=0 Then
:Goto l1
:EndIf
:If d<0 Then
:Goto l2
:EndIf
:If d>0 Then
:Goto l3
:EndIf
:Lbl l1
:Disp "Une solution réelle :"
:Disp "x =",(-b)/2a
:Stop
:Lbl l2
:Disp "Deux solutions complexes :"
:Disp "x₁ =",(-b-i√(-d))/2a
:Disp "x₂ =",(-b+i√(-d))/2a
:Stop
:Lbl l3
:Disp "Deux solutions réelles :"
:Disp "x₁ =",(-b-√(d))/2a
:Disp "x₂ =",(-b+√(d))/2a
:Stop
:EndPrgm


(c'est juste du code valide, pas dit que ça marche)

[Amayarux]

Voici maintenant le nouvel algorithme modifié mais toujours l'erreur "syntaxe" :

Code: Select all

Define trinôme()=
Prgm
:Disp "f(x)=ax²+bx+c"
:Request "Entrez a",a
:While a=0
:Disp "Erreur : a≠0"
:Request "Entrez a",a
:EndWhile
:Request "Entrez b",b
:Request "Entrez c",c
:d:=b^(2)-4*a*c
:Disp "Discriminant Δ =",d
:If d=0 Then Goto l1
:EndIf
:If d<0 Then Goto l2
:EndIf
:If d>0 Then Goto l3
:EndIf
:Lbl l1
:Disp "Une solution réelle :"
:Disp "x =",(-b)/2*a
:Stop
:Lbl l2
:Disp "Deux solutions complexes :"
:Disp "x₁ =",(-b-√(-d))/2a
:Disp "x₂ =",(-b+√(-d))/2a
:Stop
:Lbl l3
:Disp "Deux solutions réelles :"
:Disp "x₁ =",(-b-√(d))/2a
:Disp "x₂ =",(-b+√(d))/2a
:Stop
:EndPrgm

[Amayarux]

Je reviens vous voir pour cette fois un problème avec la dichotomie :

Code: Select all

Define dichotomie()=
Prgm
:Request "Entrez la fonction f :",f
:Request "Entrez la borne a :",a
:Request "Entrez la borne b :",b
:While a>b
:Disp "Erreur : la borne a doit être inférieure à la borne b"
:Request "Entrez la borne a :",a
:Request "Entrez la borne b :",b
:EndWhile
:Request "Entrez la précision e :",e
:While b-a>e
:Local c,d
:c:=f|x=a
:d:=f|x=((a+b)/(2))
:If c*d<0 Then
:b:=((a+b)/(2))
:Else
:a:=((a+b)/(2))
:EndIf
:EndWhile
:Disp "α∈]",a,";",b,"["
:EndPrgm


[Excale]

Code: Select all

Define z()=
Prgm
Request "Entrez la fonction f :",f
Request "Entrez la borne a :",a
Request "Entrez la borne b :",b
While a>b
Disp "Erreur : la borne a doit être inférieure à la borne b"
Request "Entrez la borne a :",a
Request "Entrez la borne b :",b
EndWhile
Request "Entrez la précision e :",e
Disp "Excale"
While false
Local c,d
c:=f|x=a
d:=f|x=((a+b)/(2))
If c*d<0 Then
b:=((a+b)/(2))
Else
a:=((a+b)/(2))
EndIf
EndWhile
Disp "a?]",a,";",b,"["
:EndPrgm

[marseille]

Code: Select all

Define trinome()=
Prgm
: Disp "f(x)=ax²+bx+c"
: Request "Entrez a",a
: While a=0
:  Disp "Erreur : a≠0"
:  Request "Entrez a",a
: EndWhile
: Request "Entrez b",b
: Request "Entrez c",c
: d:=b^(2)-4*a*c
: Disp "Discriminant Δ =",d
: If d=0 Then
:  Disp "Une solution réelle :"
:  Disp "x =",((−b)/(2))*a
: ElseIf d<0 Then
:  Disp "Deux solutions complexes :"
:  Disp "x₁ =",((−b-i*√(−d))/(2))*a
:  Disp "x₂ =",((−b+i*√(−d))/(2))*a
: ElseIf d>0 Then
:  Disp "Deux solutions réelles :"
:  Disp "x₁ =",((−b-√(d))/(2))*a
:  Disp "x₂ =",((−b+√(d))/(2))*a
: EndIf
:EndPrgm


Dans cette version, il n'y a plus de Goto, et plus de message d'erreur non plus. Je pense que ton erreur provenait de ces gotos vers un label à l'extérieur du if. Je n'en suis cependant pas certain à 100%, n'utilisant pas, autant que possible, l'instruction goto. Il vaut d'ailleurs mieux l'éviter. Ca crée des programmes "spaghetti" avec des labels de branchement partout; ça rend le programme illisible; et c'est une source non négligeable non seulement d'erreurs, mais de localisation de ces mêmes erreurs, quand après tu essaies de déboguer ce programme.

Tu peux simplifier encore ton programme en utilisant le solveur. Ton programme se raccourcirait considérablement (le gros if... elseif... endif disparaît). Mais dans ce cas, tu ne verrais plus que le résultat final et le calcul du discriminant n'apparaitrait plus. A toi de voir si c'est important pour toi. Ou alors, tu le recalcules séparément avant d'utiliser Solve. La fonction Solve renvoie les résultats sous une forme destinée à l'affichage, que tu convertis en liste (à l'aide de la fonction exp▶list), contenant dans le cas d'équation du second degré, 0,1 ou 2 résultats en fonction des paramètres d'entrée. La fonction s'écrit alors :

: res:=exp▶list(solve(a*x^(2)+b*x+c=0,x),x)

Tu peux ensuite, soit afficher res telle quelle avec "Disp res".

Ton programme devient alors:

Code: Select all

Define trinome()=
Prgm
: Disp "f(x)=ax²+bx+c"
: Request "Entrez a",a
: While a=0
:  Disp "Erreur : a≠0"
:  Request "Entrez a",a
: EndWhile
: Request "Entrez b",b
: Request "Entrez c",c
: d:=b^(2)-4*a*c
: Disp "Discriminant Δ =",d
: res:=exp▶list(solve(a*x^(2)+b*x+c=0,x),x)
: Disp res
:EndPrgm


En sortie, ça donne ça:

f(x)=ax²+bx+c
Entrez a 1
Entrez b −6
Entrez c 3
Discriminant Δ = 24
{−(√(6)-3),√(6)+3}

Tu peux aussi afficher les éléments de la liste séparément, sachant que le nombre d'éléments dans la liste s'obtient par "Dim(res)", et les éléments par res[1], et res[2] le cas échéant.

[Bisam]

Moi, je préfère les fonctions :

Code: Select all

Define trinome(a,b,c)=Func
local d
If a=0
return "Le coefficient a devant x^2 doit être non nul !"
d:=b^2-4*a*c
when(d=0,{"Une racine réelle double",-b/(2*a)},{"Deux racines " &when(d>0,"réelles","complexes conjuguées"),(-b+{-1,1}√d)/(2*a)})
EndFunc

On utilise à fond les possibilités de simplifications et de calculs simultanés de la calculette.